ASP编写完整的一个IP所在地搜索类

来源:岁月联盟 编辑:zhu 时间:2003-07-04
<%
Server.ScriptTimeout = &H3C
Response.Buffer = ("S.F." = "S.F.")
Dim IpSearch
'建立对象
Set IpSearch = New clsIpSearch
' 该句建立SQL Server的IP地址库的连接,可使用默认连接,但要保证存在wry.mdb
IpSearch.ConnectionString = "DRIVER={SQL Server};SERVER=hostname:UID=sa;PWD=;DATABASE=Ip"
' 设置要查询的IP,可用默认值,这里设置的是 127.0.0.1
IpSearch.IpAddress = &H7F & "." & &H00 & "." & &H00 & "." & &H01
' 取得IP 所在地,反馈值有三个,以逗号分割
' 格式为:所在国家或地区,当地上网地区,提供正确IP地址信息的用户名
Response.Write ("所在地:" & IpSearch.GetIpAddrInfo() & "<br>")
' 取出IP地址
Response.Write ("IP:" & IpSearch.IpAddress & "<br>")
' 将IP地址转换为数值
Response.Write ("IP转换为数值:" & IpSearch.CLongIP(IpSearch.IpAddress) & "<br>")
' 将IP地址转换为数值后还原成IP字符串
Response.Write ("数值还原成IP:" & IpSearch.CStringIP(IpSearch.CLongIP(IpSearch.IpAddress)) & "<br>")
Response.Write ("<hr>")
%>
<%
Class clsIpSearch
'##################################################################
'声明:本程序采用的数据为网络上著名的IP工具软件《追捕》作者“冯志宏”
'先生所精心搜集整理。
'《追捕》数据库的转换方法:
'修改wry.dll 文件后缀名称为 wry.dbf
'方法一:
' 启动Access 数据,选择打开数据库,选择打开的文件类型为“dBASE 5 (*.dbf)”
' 打开wry.dbf文件,选择《工具》菜单下的《数据库实用工具》中的《转换数据库》
' 选择《转换为 Access 97 格式(版本可选)》功能,保存文件即可成为MDB格式。
'方法二:
' 使用SQL Server提供的《导入和导出数据》向导。
' 方法简要说明:在ODBC 控制面板中设置指向wry.dbf的DSN。
' 使用《导入和导出数据》向导,选择其正确的驱动程序和要导入的库即可。
' 或者直接导入由方法一生成的MDB文件入库。
'方法三:
' 使用Access 打开wry.dbf 文件后将自动通过MDB库引用原库数据。
'
'未安装其他数据库平台,其他方法欠考虑。
'###################### 类说明 ####################################
'# IP 所在地搜索类
'# ConnectionString 为数据库连接声明,默认声明同级目录的wry.mdb
'# IpAddress 请设置为进行搜索的IP 地址,默认取当前访问者IP
'# 类建立方法
'# Dim objVal '声明一个变量
'# Set objVal = New clsIpSearch '建立类对象
'# Response.Write (objVal.IpAddress) '显示当前访问者IP
'# IP 搜索类方法列表:
'# .CLongIP '将IP地址转换为长整型的数值
'# 参数:asNewIP '要转换的IP地址字符串
'# .CStringIP '将长整型的数值转换为IP
'# 参数:anNewIP '要还原为IP地址的数值
'# .GetClientIP '取访问者的IP
'# .GetIpAddrInfo '得到设置过IpAddRess属性的IP所在地
'# 属性列表(自动初始化):
'# ConnEctionString 'ADo 访问数据库连接说明
'# IpAddress '要操作的IP地址
'# 内部错误处理:
'# 欠缺,未做,请自行补充。
'##################################################################

Public ConnectionString
Public IpAddress
Private DBConn '连接对象,模块级声明
'────────────────────────────────
' 类初始化
Private Sub Class_initialize()
' 这里建立的是通过“数据转换--方法一”生成的mdb 库文件
ConnectionString="DRIVER={Microsoft Access Driver (*.mdb)};DBQ=" & Server.MapPath("wry.mdb")
IpAddress = GetClientIP()
Set DBConn = OpenConnection()
End Sub
'────────────────────────────────
' 类注销
Private Sub Class_Terminate()
ConnectionString = Null
IpAddress = Null
DBConn.Close
Set DBConn = Nothing
End Sub
'────────────────────────────────
' 建立一个连接
Private Function OpenConnection()
Dim tmpConn
Set tmpConn=Server.CreateObject("ADODB.Connection")
tmpConn.Open ConnectionString
Set OpenConnection=tmpConn
Set tmpConn=nothing
End Function
'────────────────────────────────
' 执行一个SQL命令,并返回一个数据集对象
Private Function SQLExeCute(strSql)
Dim Rs
Set Rs=DBConn.ExeCute(strSQL)
Set SQLExeCute = Rs
Set Rs=nothing
End Function
'────────────────────────────────
' 转换一个数值为IP
Public Function CStringIP(ByVal anNewIP)
Dim lsResults
Dim lnTemp
Dim lnIndex
For lnIndex = &H03 To &H00 Step -&H01
lnTemp = Int(anNewIP / (&H100 ^ lnIndex))
lsResults = lsResults & lnTemp & "."
anNewIP = anNewIP - (lnTemp * (&H100 ^ lnIndex))
Next
lsResults = Left(lsResults, Len(lsResults) - &H01)
CStringIP = lsResults
End function
'────────────────────────────────
' 转换一个IP到数值
Public Function CLongIP(ByVal asNewIP)
Dim lnResults
Dim lnIndex
Dim lnIpAry
lnIpAry = Split(asNewIP, ".", &H04)
For lnIndex = &H00 To &H03
if Not lnIndex = &H03 Then
lnIpAry(lnIndex) = lnIpAry(lnIndex) * (&H100 ^ (&H03 - lnIndex))
End if
lnResults = lnResults + lnIpAry(lnIndex)
Next
CLongIP = lnResults
End function
'────────────────────────────────
' 取Client IP
Public Function GetClientIP()
dim uIpAddr
' 本函数参考webcn.Net/AspHouse 文献<取真实的客户IP>
uIpAddr = Request.ServerVariables("HTTP_X_FORWARDED_FOR")
If uIpAddr = "" Then uIpAddr = Request.ServerVariables("REMOTE_ADDR")
GetClientIP = uIpAddr
uIpAddr = ""
End function
'────────────────────────────────
' 读取IP所在地的信息
Public function GetIpAddrInfo()
Dim tmpIpAddr
Dim IpAddrVal
Dim ic,charSpace
Dim outTime
outTime = Timer
charSpace = ""
IpAddrVal = IpAddress
'将IP字符串劈开成数组好进行处理
tmpIpAddr = Split(IpAddrVal,".",-1,1)
For ic = &H00 To Ubound(tmpIpAddr)
'补位操作,保证每间隔满足3个字符
Select Case Len(tmpIpAddr(ic))
Case &H01 :charSpace = "00"
Case &H02 :charSpace = "0"
Case Else :charSpace = ""
End Select
tmpIpAddr(ic) = charSpace & tmpIpAddr(ic)
Next
IpAddrVal = tmpIpAddr(&H00) & "." & tmpIpAddr(&H01) & "." & tmpIpAddr(&H02) & "." & tmpIpAddr(&H03)

'以下为查询,IP地址库基于《追捕》的IP数据库,感谢"冯志宏"先生的贡献
'库结构如下:
'CREATE TABLE [dbo].[wry] (
' [STARTIP] [nvarchar] (17) COLLATE Chinese_PRC_CI_AS NULL , --起始IP段
' [ENDIP] [nvarchar] (17) COLLATE Chinese_PRC_CI_AS NULL , --终止IP段
' [COUNTRY] [nvarchar] (16) COLLATE Chinese_PRC_CI_AS NULL , --国家或者地区
' [LOCAL] [nvarchar] (54) COLLATE Chinese_PRC_CI_AS NULL , --本地地址
' [THANK] [nvarchar] (23) COLLATE Chinese_PRC_CI_AS NULL --感谢修正IP地址用户姓名
') ON [PRIMARY]
'经过分析库的数据存放结构,总结出准确的查询方法,具体看下面的查询过程
'假设查询的IP为 127.0.0.1,对照库数据将其修改为127.000.000.001
'然后各搜索两次'startIP'字段和'endIP'字段,分别分割字符长度为11,7
'这样在前两次搜索startIP 未找到正确数据,将对比endIP字段。
'如果按如下顺序查找,任何一条语句满足将停止查询
'SELECT * FROM wry WHERE LEFT(LTrim(RTrim(startIP)),11) = '127.000.000'
'SELECT * FROM wry WHERE LEFT(LTrim(RTrim(startIP)),7) = '127.000'
'SELECT * FROM wry WHERE LEFT(LTrim(RTrim(endIP)),11) = '127.000.000'
'SELECT * FROM wry WHERE LEFT(LTrim(RTrim(endIP)),7) = '127.000'
'本原意打算采用一次查询得到结果,但本人sql 查询表达式的功力不够,会发生
'查出有两条记录的数据,考虑到这种小范围的数据查询速度很快所以采用这种比较
'直观的查询完成。关注朋友修正,感谢。
For ic = &H01 To &H04
Select Case ic
Case &H01:
'查询startIP 字段,取位 11
charSpace = GetDbIpInfo(IpAddrVal,&H0B,"startIP")
If Len(charSpace)>&H00 Then Exit For
Case &H02:
'查询startIP 字段,取位 7
charSpace = GetDbIpInfo(IpAddrVal,&H07,"startIP")
If Len(charSpace)>&H00 Then Exit For
Case &H03:
'查询endIP 字段,取位 11
charSpace = GetDbIpInfo(IpAddrVal,&H0B,"endIP")
If Len(charSpace)>&H00 Then Exit For
Case &H04:
'查询endIP 字段,取位 7
charSpace = GetDbIpInfo(IpAddrVal,&H07,"endIP")
If Len(charSpace)>&H00 Then Exit For
End Select
Next
If Len(charSpace)=&H00 Then
GetIpAddrInfo =false
Else
GetIpAddrInfo = charSpace
End If
end function
'────────────────────────────────
' 返回数据查询的字符串
Private function GetDbIpInfo(byVal IpAddr,byVal IpLength,byVal findmethod)
Dim OpenIPsearch
Dim strSQL
Dim result
strSQL = "SELECT * FROM wry WHERE LEFT(LTrim(RTrim(" & findmethod & "))," & IpLength & ") = '" & Left(Trim(IpAddr),IpLength) & "'"
Set OpenIPsearch = SQLExeCute(strSQL)
If Not OpenIPsearch.Eof Then
result = OpenIPsearch(NullToSpace("COUNTRY")) & "," & OpenIPsearch(NullToSpace("LOCAL")) & "," & OpenIPsearch(NullToSpace("THANK"))
Else
result = Null
End If
OpenIPsearch.Close
Set OpenIPsearch = Nothing
GetDbIpInfo = result
end function
'────────────────────────────────
' 将数据库空记录转换为空字符
Private function NullToSpace(byVal rsStr)
If isNull(rsStr) Then
NullToSpace = ""
Else
NullToSpace = Trim(rsStr)
End If
End Function
End Class
%>