Win32汇编教程七

有关控件子类化
说到类，大家可能马上就想到C++，的确，类首先是在C中提出的，但是，这个概念在 Win32Asm 中仍然适用，因为在类的思路是这样的：先假设某个对象有不同的属性，当一个新的对象的某个属性和上面所说的对象有些不同，而别的属性一模一样，那么实际上除了处理这个属性的代码有些不同外，别的代码完全可以使用前面的对象的代码。在具体的应用中，我举个例子，比如说我们定义一个 "edit" 控件，那么这个控件的行为是由 Windows 内定的，因为它的窗口过程是在 Windows 系统内部的，但假如我们想编一个有语法检查的 "edit" 控件，是否我们除了语法检查的代码以外，还要编写很多代码来实现老的 "edit" 控件一模一样的功能呢？答案当然是否定的，实际上，我们可以截获一个标准 "edit"控件的 WM_CHAR 消息，检查键入的键并做处理，别的消息可以传给原来的窗口过程。示意如下：

在子类化之前： Windows => edit 控件的窗口过程

在子类化之后： Windows => 我们的过程代码 => edit 控件的窗口过程

在Windows 的 API 中有个函数可以用来实现这个功能，那就是 SetWindowLong PROTO hWnd,nIndex,dwNewLong ，参数的意思是 hWnd 是你要改变的窗口句柄，nIndex 是我们要改变窗口的什么属性，它的值可以是 GWL_EXSTYLE：改变窗口风格，GWL_WNDPROC：设置窗口的新的过程，这正是我们感兴趣的，还有是 GWL_USERDATA 这是窗口自定义的一个32位的数据。dwNewLong 是新的值，还有一个 API 是用来调用原来的窗口过程的，叫 CallWindwoProc PROTO lpPrevWndFunc,hWnd,Msg,wParam,lParam。
我们在使用时有下面的过程：

用 SetWindowLong,hWnd,GWL_WNDPROC,addr _NewProcAddress 设置我们自己的代码的地址，API 返回原来的过程地址
用 SetWindowLong,hWnd,GWL_USERDATA,eax 把原来的过程地址保存在自定义数据中。
这样，所有消息会先送到我们的过程中，然后在我们自己的过程中：
对要处理的消息进行处理，如果不希望原来的过程再处理，那么返回。
对自己不处理的消息，调用原来的窗口过程处理，并把返回值返回。方法是：
用 invoke GetWindowLong,hWnd,GWL_USERDATA 取出自定义数据中保存的原过程地址
用 invoke CallWindowProc,eax,hWnd,uMsg,wParam,lParam 调用原过程 UINT uStructSize}
本节教程提供了一个源程序，它是实现对话框中的文本的 URL 连接过程，我们看到有的程序中的文本是蓝色的，有下划线，然后鼠标移动到上面会变手型，就象浏览器中的超联结一样，而且按下会自动连接到网站上，仔细想想，我们并没有一个标准的控件或 API 来实现这样一个功能，因为这首先是一个文本，所以我们可以对这个文本进行子类化，处理它的WM_LBUTTONUP 消息来实现按下自动连上网站的功能；处理 WM_SETCURSOR 消息来让鼠标移到上面改变光标，具体源程序如下：

源程序 - 资源文件

;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
;************************************************
#include

;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; Icon 1000 开始
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
#define IDI_MAIN 1000
#define IDC_HANDLE 2000

;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 对话框 3000 开始
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
#define DLG_ABOUT 3000

#define ID_EMAIL 3001
#define ID_HOMEPAGE 3002

;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 资源定义开始
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
IDI_MAIN ICON  "Main.ico"
IDC_HANDLE CURSOR  "Handle.cur"
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
DLG_ABOUT DIALOG DISCARDABLE 50, 50, 160, 30
STYLE  DS_MODALFRAME | WS_POPUP | WS_CAPTION | WS_SYSMENU
CAPTION  "URL 联结文本演示 - by 罗云彬"
FONT  9, "宋体"
BEGIN
LTEXT  "我的主页:   ",-1,   5,5,54,9
LTEXT  "http://asm.yeah.net", ID_HOMEPAGE, 55,5,80,9
LTEXT  "我的E-mail: ",  -1,  5,17,54,9
LTEXT  "bigluo@telekbird.com.cn",ID_EMAIL, 55,17,95,9
END

源程序 - 汇编源文件

;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 是否包括调试代码
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
DEBUG = 0
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; Programmed by 罗云彬, bigluo@telekbird.com.cn
; Website: http://asm.yeah.net
; LuoYunBin's Win32 ASM page (罗云彬的编程乐园)
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 版本信息
; 窗口子类化演示程序 Ver 1.0
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>

  .386
  .model flat, stdcall
  option casemap :none   ; case sensitive

;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; Include 数据
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>

include  windows.inc
include  user32.inc
include  kernel32.inc
include  comctl32.inc
include  comdlg32.inc
include  shell32.inc
include  gdi32.inc

includelib user32.lib
includelib kernel32.lib
includelib comctl32.lib
includelib comdlg32.lib
includelib shell32.lib
includelib gdi32.lib

;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; Equ 数据
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>

IDI_MAIN equ 1000 ;icon
IDC_HANDLE equ 2000 ;handle cursor

DLG_ABOUT equ  3000  ;dialog - about
ID_EMAIL equ  3001
ID_HOMEPAGE equ  3002

;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 数据段
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>

.data?

hInstance dd ?
hIcon dd ?

szBuffer db 256 dup (?)

;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
_HyperLinkProc proto :DWORD,:DWORD,:DWORD,:DWORD
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>

.data

hCursorHandle dd ?
szHomePage db "http://asm.yeah.net",0
szEmail db "mailto:bigluo@telekbird.com.cn"
db "?subject=嗨！我喜欢你的程序！",0

.code

if DEBUG
include Debug.asm
endif
;********************************************************************
; 关于对话框中超级连接的窗口程序
;********************************************************************
_HyperLinkProc proc hWnd:DWORD,uMsg:DWORD,wParam:DWORD,lParam:DWORD

  mov eax,uMsg
  .if eax == WM_LBUTTONUP
   invoke GetDlgCtrlID,hWnd
   .if eax == ID_HOMEPAGE
    invoke ShellExecute,0,0,offset szHomePage,0,0,0
   .elseif eax == ID_EMAIL
    invoke ShellExecute,0,0,offset szEmail,0,0,0
   .endif
  .elseif eax == WM_NCHITTEST
;将 WM_NCHITTEST 返回 TRUE 可以接收鼠标动作，实现按下功能 !
   mov eax,TRUE
   ret
  .elseif eax == WM_SETCURSOR
   invoke SetCursor,hCursorHandle
  .else
   invoke GetWindowLong,hWnd,GWL_USERDATA
   invoke CallWindowProc,eax,hWnd,uMsg,wParam,lParam
   ret
  .endif
  xor eax,eax
  ret

_HyperLinkProc endp
;********************************************************************
; 对话框窗口主程序
;********************************************************************
AboutDialogProc proc uses ebx edi esi, \
  hWnd:DWORD,uMsg:DWORD,wParam:DWORD,lParam:DWORD
  local @stWindow:RECT
  local @dwWidth:DWORD,@dwHeight:DWORD
  local @hWinTemp:DWORD
  local @stFont:LOGFONT,@hFontOutput:DWORD

  mov eax,uMsg
  .if eax == WM_CLOSE
   invoke EndDialog,hWnd,NULL
  .elseif eax == WM_INITDIALOG
   invoke GetModuleHandle,NULL
   invoke LoadCursor,eax,IDC_HANDLE
   mov hCursorHandle,eax
   invoke GetDlgItem,hWnd,ID_HOMEPAGE
   mov @hWinTemp,eax
   invoke SetWindowLong,@hWinTemp,GWL_WNDPROC,addr _HyperLinkProc
   invoke SetWindowLong,@hWinTemp,GWL_USERDATA,eax
   invoke GetDlgItem,hWnd,ID_EMAIL
   mov @hWinTemp,eax
   invoke SetWindowLong,@hWinTemp,GWL_WNDPROC,addr _HyperLinkProc
   invoke SetWindowLong,@hWinTemp,GWL_USERDATA,eax
  .elseif eax == WM_CTLCOLORSTATIC
   invoke GetDlgCtrlID,lParam
   .if eax == ID_HOMEPAGE || eax == ID_EMAIL
    invoke SendMessage,lParam,WM_GETFONT,0,0
    mov @hFontOutput,eax
    invoke GetObject,@hFontOutput,sizeof LOGFONT,addr @stFont
    mov @stFont.lfUnderline,TRUE
    invoke CreateFontIndirect,addr @stFont
    mov @hFontOutput,eax
    invoke SelectObject,wParam,eax
    invoke SetTextColor,wParam,Blue
    invoke GetSysColor,COLOR_MENU
    invoke SetBkColor,wParam,eax
    invoke DeleteObject,@hFontOutput
;********************************************************************
; 注意此处一定要把StockOject的返回值返回，否则无法显示颜色
;********************************************************************
    invoke GetStockObject,HOLLOW_BRUSH
   .else
    mov eax,FALSE
    ret
   .endif
   ret
  .else
;********************************************************************
; 注意：对话框的消息处理后，要返回 TRUE,对没有处理的消息
; 要返回 FALSE
;********************************************************************
   mov eax,FALSE
   ret
  .endif
  mov eax,TRUE
  ret

AboutDialogProc endp

;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 程序开始
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>

start:
  invoke InitCommonControls
  invoke GetModuleHandle,NULL
  mov hInstance,eax
  invoke DialogBoxParam,hInstance,DLG_ABOUT,\
   NULL,offset AboutDialogProc,DLG_ABOUT
  invoke ExitProcess,NULL
;********************************************************************
  end start
程序的分析和要点

在资源中，我们定义了两个文本框，ID 分别为 ID_HOMEPAGE 和 ID_EMAIL，在主对话框的过程的 initdialog 消息中，我们用 GetDlgItem 取的它们的 hWnd，然后进行子类化，我们把新的过程设置到了 _HyperLinkProc 中

   invoke GetDlgItem,hWnd,ID_HOMEPAGE
   mov @hWinTemp,eax
   invoke SetWindowLong,@hWinTemp,GWL_WNDPROC,addr _HyperLinkProc
   invoke SetWindowLong,@hWinTemp,GWL_USERDATA,eax
   invoke GetDlgItem,hWnd,ID_EMAIL
   mov @hWinTemp,eax
   invoke SetWindowLong,@hWinTemp,GWL_WNDPROC,addr _HyperLinkProc
   invoke SetWindowLong,@hWinTemp,GWL_USERDATA,eax

然后在新的处理过程中，检测到 WM_LBUTTONUP 消息（鼠标左键放开）就使用 ShellExecute API 来连到网站，检测 WM_NCHITTEST 来使文本控件接收鼠标的消息，检测 WM_SETCURSOR 消息把光标设置成手形，对这些消息以外的消息我们是不处理的，那就用 CallWindowProc 来调用原来的过程进行处理。

  .if eax == WM_LBUTTONUP
   invoke GetDlgCtrlID,hWnd
   .if eax == ID_HOMEPAGE
    invoke ShellExecute,0,0,offset szHomePage,0,0,0
   .elseif eax == ID_EMAIL
    invoke ShellExecute,0,0,offset szEmail,0,0,0
   .endif
  .elseif eax == WM_NCHITTEST
;将 WM_NCHITTEST 返回 TRUE 可以接收鼠标动作，实现按下功能 !
   mov eax,TRUE
   ret
  .elseif eax == WM_SETCURSOR
   invoke SetCursor,hCursorHandle
  .else
   invoke GetWindowLong,hWnd,GWL_USERDATA
   invoke CallWindowProc,eax,hWnd,uMsg,wParam,lParam
   ret
  .endif